Function ToNumber(Value)
	    If IsNumeric(Value) Then
	        ToNumber = CInt(Value)
	    Else
	        ToNumber = -1
	    End If
	End Function

	Function ValidateDate(sDate)
    Dim lMonth
    Dim lDay
    Dim lYear
    Dim Pos
    Dim i
    Dim OK

        'Search Month
        Pos = InStr(1, sDate, "/")
        If Pos > 1 Then
            lMonth = ToNumber(Mid(sDate, 1, Pos - 1))
            'Verify if it's a valid Month
            If lMonth >= 1 And lMonth <= 12 Then
                Pos = Pos + 1
                i = Pos
                'Search Day
                Pos = InStr(Pos, sDate, "/")
                If Pos > i Then
                    'Verify if Day part is numeric
                    lDay = ToNumber(Mid(sDate, i, Pos - i))
                    'Preverify if it's a valid Day
                    If lDay >= 1 And lDay <= 31 Then
                        lYear = ToNumber(Mid(sDate, Pos + 1))
                        'Verify if it's a valid Year
                        If (lYear >= 1900 And lYear <= 2079) Or (lYear >= 0 And lYear <= 99) Then
                            'Verify if it's a valid Day
                            If lMonth = 2 Then
                                If lDay <= 28 Then
                                    OK = True
                                ElseIf lDay = 29 Then
                                    OK = ((lYear Mod 4) = 0)
                                End If
                            ElseIf lDay = 31 Then
                                OK = Not (lMonth = 4 Or lMonth = 6 Or lMonth = 9 Or lMonth = 11)
                            Else
                                OK = True
                            End If
                        End If
                    End If
                End If
            End If
        End If
        ValidateDate = OK
    End Function

	'Validate Date From and Date To
	Function ValidateDatesFromTo(DateFrom, DateTo)
	Const MessageInfo = ". Please verify it and try again"
	Const MessageFrom = "Invalid 'Date From'"
	Const MessageTo = "Invalid 'Date To'"
	Const MessageInconsistence = "The 'Date From' is Greater than 'Date To'"
		'Verify Valid DateFrom
		If ValidateDate(DateFrom.value)=False Then
			msgbox MessageFrom & MessageInfo,48
			DateFrom.focus
		'Verify Valid DateTo
		ElseIf ValidateDate(DateTo.value)=False Then
			msgbox MessageTo & MessageInfo,48
			DateTo.focus
		'Verify Valid DateFrom And DateTo Relationship
		ElseIf CDate(DateFrom.value)>CDate(DateTo.Value) Then
			msgbox MessageInconsistence & MessageInfo,48
			DateFrom.focus
		Else
			ValidateDatesFromTo=True
		End If
	End Function